Offene Steuerung mit Encoder und Autoguider

void lx200Controll()
{
  //************ LX200  CONTROLL
  int inByte;
  short d1, d2, d3;
  
  if (Serial.available() > 0) { 
    // get incoming byte:
    inByte = Serial.read();
    if (inByte == -1) return;
    
    if (pos >= (sizeof buf / sizeof buf[0] - 1)) {
      pos = 0; 
      buf[pos] = 0;
      //  ERRO
    }
  
    if (inByte != '#') {
      if((inByte != (char)32) && (inByte !=(char)10) && (inByte != (char)13) && (inByte != '0xDF')) 
      {
        buf[pos++] = inByte;
        buf[pos] = 0;
      }
    }
    else
    {
      if (buf[0] == ':')
      {
        //*********************************************
        //************ MAIN lx200 switch **************
        switch (buf[1])
        {
          
          //*****************
          // All :M* commands
          //*****************
          case 'M':
            switch(buf[2])
            {   
              case 'n':
                //  Motor north - :Mn
                RunDEC_FWD(true);
              break;
              case 's':
                // Motor south - :Ms
                RunDEC_REV(true);
              break;
              case 'w':
                // Motor west - :Mw
                RunRA_FWD(true);
              break;
              case 'e':
                // Motor east - :Me
                RunRA_REV(true);
              break;
  
              //PulseGuide
              case 'g':
              switch(buf[3])
              {          
                case 'n':
                  //  Motor north - :MgnDDDD#
                  RunDEC_FWD(true);
                  readDigit(buf + 4, pulseGuideDurationDEC); 
                  pulseGuideStartDEC = millis();
                break;
                case 's':
                  // Motor south - :MgsDDDD#
                  RunDEC_REV(true);
                  readDigit(buf + 4, pulseGuideDurationDEC); 
                  pulseGuideStartDEC = millis();
                break;
                case 'w':
                  // Motor west - :MgwDDDD#
                  RunRA_FWD(true);
                  readDigit(buf + 4, pulseGuideDurationRA); 
                  pulseGuideStartRA = millis();
                break;
                case 'e':
                  // Motor east - :MgeDDDD#
                  RunRA_REV(true);
                  readDigit(buf + 4, pulseGuideDurationRA); 
                  pulseGuideStartRA = millis();
                break;
              }
              break;      
              
              case 'S':
                // gotoTarget - :MS
                if(chuckControl ==1)
                {
                  //Manuelles synchronisieren über den Nunchuck
                  syncScope();
                  //Serial.print("0");
                  sp0();
                }
                else
                {
                  if(Synchronized){
                    gotoStartSlew = millis();
                    GoTargetRA(RAHour, RAMinute, RASecond); 
                    GoTargetDEC(DECSign, DECDegree, DECMinute, DECSecond);
                    //Serial.print("0");
                    sp0();
                  }else{
                    //Nicht synchronisiert
                    //Serial.print("1");
                    sp1(); 
                  }
                }
              break;
            }
          break;
          //*****************
          // All :Q* commands
          //*****************
          case 'Q':
            switch(buf[2])
            {
              case 0:
              //Halt everything - :Q
                  motor=DEC_M;
                  dSPIN_SoftStop(); 
              break;
              case 'e':
              case 'w':
                // Halt east and west slews - :Qe or :Qw
    	        RunRA_FWD_STAR(); 
              break;
              case 's':
              case 'n':
                // Halt north and south slews - :Qs or :Qn
    	        motor=DEC_M;
                dSPIN_SoftStop();
              break;
            }
          break;
          //*****************
          // All :S* commands
          //***************** 
          case 'S':
            switch(buf[2])
            {
              case 'r':
                // Set target object RA, format #:Sr HH:MM:SS#
    	        stora();
              break;
              case 'd':
                // Set target object declination, format #:Sd +DD:MM:SS#
                stodec();
              break;
              case 'S':
                slst();
              break;
            }
          break;
          //*****************
          // All :R* commands
          //***************** 
          case 'R':
             switch(buf[2])
            {
              case 'G':
                // Set slew rate to Guiding Rate (slowest) :RG
				lx200SPDSid = guideSpdSid;
              break;
              case 'S':
                // Set Slew rate to max (fastest) :RS
                lx200SPDSid = runSpdArray[7];
              break;
            }
          break;
          //*****************
          // All :G*-commands
          //*****************    
          case 'G':  
            switch(buf[2])
            {
              case 'W':
              //TODO
              // get scope alligment status 
				// returns <mount><tracking><aligement>#
                // mount: A=azEl mounted, P=Equatorial mounted, G=german mounted equatorial
                // Only support G
                // tracking: T=Tracking, N=non Tracking
                // alligemnt: 0-needs alligment, 1=one star alligment, 2= two star, 3=three star
                // alwas return 0
              break;
              case 'S':
                //:GS# Get the Sidereal Time
                //Returns: HH:MM:SS#
				gst();
			  break;
              case 't':
            
  			  break;
              case 'g':
            
              break;
              case 'C':
                //TODO
                // get current date
                // returns MM/DD/YY#
              break;
              case 'c':
                // Get Calendar Format - :Gc
    	        Serial.print("24#");
              break;
              case 'L':
                // get local time in 24 h format
				// returns HH:MM:SS#
              break;
              case 'T':
                // Gets the current track 'frequency' - :GT
    	        
              break;
              case 'M':
                // Gets site name - :GM
    	        Serial.print("Arduino");
                Serial.print("#");
              break;
              case 'I':
                // Initialize Telescope - :I
              break;
              case 'D':
                // Get Telescope DEC - :GD
                gd();
              break;
              case 'd':
                // Get Currently Selected Object/Target Declination Returns: sDD*MM# or sDD*MM’SS#
				gdt();
              break;
              case 'R':
                // Get Telescope RA - :GR
                gr();
              break;
              case 'r':
                // Get current/target object RA Returns: HH:MM.T# or HH:MM:SS
                grt();
              break;
            }
          break;
          //*****************
          // All :C* commands
          //***************** 
          case 'C':
            switch(buf[2])
            {
              case 'M':
                // Synchronizes the telescope's position with the currently selected database object's coordinates
                syncScope();
                Serial.print("sync#");
              break;
            }
          break;
        }
      }
      pos = 0;
      buf[pos] = 0;
    }
  } 
}